Function pointers

A function pointer is a pointer that points to a function. Function pointers are useful for passing functions as arguments to other functions, or for storing functions in a variable.

Declaring a function pointer

A function pointer is declared using the func keyword, followed by <, the types of the parameters separated by a comma, the return type of the function and >:

func<int, int, int> add
//   ^^^  ^^^  ^^^
//    |    |    Return type
//    |    Second parameter
//    First parameter

The function pointer should always have a return type, even if the function it points to does not return a value. If the function does not return a value, the return type should be void:

func<void> callback

Calling a function pointer

A function pointer is called using the () operator, followed by the arguments of the function:

func<int, int, int> add

int result = add(1, 2)

Assigning a function pointer

A function pointer can be assigned to a function using the = operator with a existing function or lambda expression.

In the following example, the function pointer addPointer is assigned to the function add:

func<int, int, int> addPointer = add

int result = addPointer(1, 2)

int add(int a, int b) {
    return a + b
}

In the following example, the function pointer callbackPointer is assigned to a lambda expression:

func<int, int, int> callbackPointer = (a, b) => a + b

int result = callbackPointer(1, 2)

Example

The following example stores function pointers in a array and calls them:

var chars = create_pointer(0xD12A, 1)

var tick_callbacks = stackalloc func<void>[10]
var tick_callback_count = 0

// Register a callback
void register_tick_callback(func<void> callback) {
    tick_callbacks[tick_callback_count++] = callback
}

// Call all the callbacks
void tick() {
    for (int i = 0; i < tick_callback_count; i++) {
        tick_callbacks[i]()
    }
}

// Register a callback that clears the screen
register_tick_callback(() => {
    for (int i = 0; i < 17 * 17; i++) {
        chars[i] = ' '
    }
})

// Register a callback that draws a 'x' on the screen
// and moves it to the right every time it is called
var offset = 0

register_tick_callback(() => {
    chars[offset++] = 'x'
})

// Tick 3 times
tick()
tick()
tick()

// The 'x' should be on the 3rd column